Gå direkte til indholdet

Cookieindstillinger

Vælg for hver type, hvilke cookies du tillader. Du kan altid ændre dit valg via Cookieindstillinger nederst på hver side. Privatlivspolitik

Nødvendige

Altid slået til

Nødvendige for at logge ind, gemme din kurv og huske dine valg. De er altid slået til.

Hvilke cookies?
  • weboke_sessie, weboke_klant, weboke_remember: din session og at forblive logget ind
  • weboke_basket: din kurv
  • wkBtwIncl: vise priser med eller uden moms
  • wok_cookies: dit cookievalg, 12 måneder

Måler, hvilken annonce der fører til et besøg eller en bestilling, så vi ikke betaler for annoncer, der ikke virker.

Hvilke cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), op til 90 dage
  • OpenAI Ads, annoncer i ChatGPT
  • wok_aff: hvilken partner der henviste dig til os (affiliateprogram), 60 dage

4,6

Land og sprog

Hvert land har sin egen side med landets priser og moms.

Se

Læg omsætning sammen pr. måned eller pr. periode med SUM.HVISER

En kassebog, salgsliste eller timeregistrering har en dato på hver linje. Det, du vil vide, er totalen pr. måned, pr. kvartal eller mellem to datoer, eventuelt også pr. produkt. Med SUM.HVISER og to datobetingelser laver du sådan en oversigt, og den passer stadig, når der kommer flere linjer til. En pivottabel kan også klare det (se En pivottabel pr. måned, kvartal eller uge). SUM.HVISER er mere praktisk, når oversigten skal have en fast form, for eksempel til en rapport eller et budget.

Som eksempel tager vi salget hos Bloemisterij Het Zonnetje i regnearket Verkoop: i A datoen, i B produktet, i C kategorien og i D beløbet, fra række 2 til og med 300.

Trin 1: en række med måneder

Opret et regneark med navnet Oversigt. I stedet for at skrive tolv datoer laver én formel dem allesammen. Skriv i A2:

=EDATO(DATO(2026;1;1);SEKVENS(12;1;0))

SEKVENS(12;1;0) laver tallene 0 til og med 11, og EDATO lægger det antal måneder til 1. januar 2026. Du får den første dag i hver måned, fra A2 til og med A13. Giv A2:A13 det brugerdefinerede format mmmm åååå (via Flere formatter, Brugerdefineret, se Egne talformater: "12 stk", beløb i tusinder, rød ved negative tal), så står der januar 2026, februar 2026 og så videre.

Datoformatet mmmm åååå
Det brugerdefinerede format mmmm åååå viser måneden fuldt udskrevet med året

Trin 2: omsætningen pr. måned

Skriv i B2:

=SUM.HVISER(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&SLUT.PÅ.MÅNED($A2;0))

SUM.HVISER lægger de beløb sammen, hvor datoen er større end eller lig med den første dag i måneden og mindre end eller lig med den sidste dag (SLUT.PÅ.MÅNED med 0 giver slutningen af samme måned). Træk formlen ned til B13, eller markér B2:B13, før du skriver, og afslut med Ctrl+Enter.

Trin 3: pr. produkt

Sæt produktnavne som overskrifter ved siden af hinanden, for eksempel Rozen i C1, Tulpen i D1 og Boeket i E1, og skriv i C2:

=SUM.HVISER(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&SLUT.PÅ.MÅNED($A2;0);Verkoop!$B$2:$B$300;C$1)

Der kommer ét betingelsespar mere til: produktet skal være lig med overskriften. Læg mærke til dollartegnene: $A2 låser kolonnen med måneder, C$1 rækken med overskrifter. Derfor kan den samme formel stå i hele området. Hurtigt: markér først C2:E13, skriv formlen, og tryk på Ctrl+Enter. Euro-Office sætter så formlen ind i alle de markerede celler, med referencerne tilpasset til hver celle.

Omsætning pr. måned og pr. produkt
Lagt sammen pr. måned og pr. produkt. I formellinjen ses formlen fra C2, som med C$1 kigger på overskriften Rozen (1)

Tæl i stedet for at lægge sammen

Antallet af salg pr. måned tæller du med de samme betingelser og TÆL.HVISER:

=TÆL.HVISER(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&SLUT.PÅ.MÅNED($A2;0))

En fri periode

Skriv en startdato i H1 og en slutdato i I1. Omsætningen mellem dem, begge dage medregnet:

=SUM.HVISER(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Faldgruber

  • Anførselstegn og &: sammenligningen står i anførselstegn, og cellen kommer bagefter med &: ">="&H1. Skriver du ">=H1", leder Euro-Office efter teksten H1, og resultatet bliver 0.
  • Datoer med et klokkeslæt (16-11-2026 14:32) på den sidste dag i måneden falder uden for "<="&SLUT.PÅ.MÅNED(...), for den er midnat. Brug så som anden betingelse "<"&EDATO($A2;1): mindre end den første dag i den næste måned.
  • Kun på månedsnummer at filtrere, for eksempel med MÅNED() i en hjælpekolonne, lægger januar 2025 og januar 2026 sammen. Tag altid året med.
  • Datoer som tekst tælles ikke med. Se Datoer der kommer ind som tekst, eller hvor dag og måned er byttet om.

Et øjeblik…

Opsæt dine domæner

Angiv for hvert domæne navneserverne, tilknytningen til din hosting, og hvem der bliver ejer.

Indlæser dine domæner…