Gå direkte til indholdet

Cookieindstillinger

Vælg for hver type, hvilke cookies du tillader. Du kan altid ændre dit valg via Cookieindstillinger nederst på hver side. Privatlivspolitik

Nødvendige

Altid slået til

Nødvendige for at logge ind, gemme din kurv og huske dine valg. De er altid slået til.

Hvilke cookies?
  • weboke_sessie, weboke_klant, weboke_remember: din session og at forblive logget ind
  • weboke_basket: din kurv
  • wkBtwIncl: vise priser med eller uden moms
  • wok_cookies: dit cookievalg, 12 måneder

Måler, hvilken annonce der fører til et besøg eller en bestilling, så vi ikke betaler for annoncer, der ikke virker.

Hvilke cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), op til 90 dage
  • OpenAI Ads, annoncer i ChatGPT
  • wok_aff: hvilken partner der henviste dig til os (affiliateprogram), 60 dage

4,6

Land og sprog

Hvert land har sin egen side med landets priser og moms.

Se

Opslag på to betingelser på én gang

LOPSLAG og XOPSLAG slår op på én værdi (se LOPSLAG giver #N/A: sådan løser du det og XOPSLAG: opslag mod venstre og med din egen besked). I praksis søger du tit på to ting på én gang: prisen på en buket i størrelse L, en kundes takst i et bestemt år, lagerbeholdningen af et produkt i en bestemt farve. Der er tre gode måder at gøre det på, og de virker alle med almindelig Enter. En fjerde måde, som du ofte ser på internettet, virker ikke uden videre i Euro-Office.

Som eksempel bruger vi prislisten fra Bloemisterij Het Zonnetje. Det samme produkt står der flere gange, i forskellige størrelser:

ABC
1ProduktStørrelsePris
2BuketS17,50
3BuketM24,50
4BuketL34,50
5SørgedekorationM65,00
6SørgedekorationL89,00
7BrudebuketM79,50

Det produkt, du søger, står i F2 (Buket), og størrelsen i G2 (L). Vi leder efter 34,50.

Måde 1: XOPSLAG med sammensatte værdier

=XOPSLAG(F2&"|"&G2;A2:A7&"|"&B2:B7;C2:C7;"ikke fundet")

Tegnet & sætter tekst sammen. F2&"|"&G2 bliver til "Buket|L". A2:A7&"|"&B2:B7 laver den samme slags kombination af hver række i listen ("Buket|S", "Buket|M" osv.), og XOPSLAG søger i den. Stregen | imellem forhindrer, at to forskellige kombinationer tilfældigvis giver den samme tekst. Findes kombinationen ikke, for eksempel en sørgedekoration i størrelse S, får du "ikke fundet".

Opslag på produkt og størrelse
XOPSLAG i H2 (1) giver 34,50 (formlen ser du på formellinjen) for en buket i størrelse L. Nedenunder: INDEKS med multiplikation (#N/A), FILTRER, INDEKS på pristabellen, SUM.HVISER, en kombination der ikke findes, områder af forskellig længde (#VALUE!) og SUM.HVISER uden match (0)

Kigger du på formellinjen, når du har skrevet formlen, står der et @ foran A2:A7 og B2:B7. Det sætter Euro-Office selv ind, og resultatet er helt korrekt.

Måde 2: FILTRER til alle match

=FILTRER(C2:C7;(A2:A7=F2)*(B2:B7=G2);"ingen")

FILTRER giver ikke kun det første, men álle rækker, der opfylder begge betingelser. Forekommer en kombination to gange, ser du begge priser under hinanden. Sørg derfor for, at der er plads under formlen (se Lister, der opdaterer sig selv, med FILTRER, ENTYDIGE og SORTER). Vil du have "eller" i stedet for "og", bruger du et plustegn: (A2:A7="Buket")+(A2:A7="Sørgedekoration").

Måde 3: SUM.HVISER når kombinationen er unik

=SUM.HVISER(C2:C7;A2:A7;F2;B2:B7;G2)

Det lyder mærkeligt, for du vil jo ikke lægge noget sammen. Men hvis hver kombination kun forekommer én gang, er summen simpelthen den ene pris. Fordelen: SUM.HVISER er enkel og hurtig og findes i alle Excel-versioner. Ulempen: findes kombinationen ikke, får du 0 (€ 0,00) i stedet for en meddelelse. Og står kombinationen der ved en fejl to gange, får du begge priser lagt sammen.

Det du finder på internettet: INDEKS og SAMMENLIGN med en multiplikation

Mange Excel-sider foreslår =INDEKS(C2:C7;SAMMENLIGN(1;(A2:A7=F2)*(B2:B7=G2);0)). I Euro-Office giver den formel #N/A med almindelig Enter, også selvom kombinationen findes. Afslutter du den med Ctrl+Skift+Enter, får formlen tuborgklammer {…} og virker. Det glemmer man let, så brug hellere XOPSLAG eller FILTRER ovenfor.

Opslag på både række og kolonne

Står din prisliste som en tabel med produkterne under hinanden og størrelserne ved siden af hinanden (en matrix), bruger du INDEKS med to gange SAMMENLIGN. Med produkterne i A11:A13, størrelserne S, M og L i B10:D10 og priserne i B11:D13:

=INDEKS(B11:D13;SAMMENLIGN(F2;A11:A13;0);SAMMENLIGN(G2;B10:D10;0))

Den første SAMMENLIGN finder produktets række, den anden størrelsens kolonne. INDEKS henter cellen, hvor de krydser hinanden.

Hvilken skal du vælge?

SituationBedste valg
Ét svar, med en pæn meddelelse hvis det ikke findesXOPSLAG med sammensatte værdier
Filen skal også virke i en gammel ExcelSUM.HVISER
Der kan være flere matchFILTRER
Pristabel med størrelser som kolonneoverskrifterINDEKS med to gange SAMMENLIGN

Faldgruber

  • #N/A selvom kombinationen faktisk står der: ofte et mellemrum efter en værdi ("Buket ") eller et tal, der er gemt som tekst. Se LOPSLAG giver #N/A: sådan løser du det.
  • Områder af forskellig længde: =XOPSLAG(F2;A2:A7;C2:C50) giver #VALUE!. Lad alle områder begynde og slutte i samme række.
  • Hele kolonner (A:A) i disse formler gør en stor fil langsom, fordi Euro-Office så sætter en million rækker sammen. Brug et fast område som A2:A500. Se Gør et langsomt regneark hurtigere.
  • En kollega med Excel 2019 eller ældre ser #NAME? ved XOPSLAG og FILTRER.

Et øjeblik…

Opsæt dine domæner

Angiv for hvert domæne navneserverne, tilknytningen til din hosting, og hvem der bliver ejer.

Indlæser dine domæner…